Attachment 'ACDM.mod'
Download 1 // mod?le version d?finitive.
2 // 05-10-2006
3
4 var
5 // model with flexible prices (FP-model) - non linear
6 wstar $w^*$
7 Lstar $L^*$
8 Cstar $C^*$
9 mcstar $mc^*$
10 xstar $x^*$
11 Istar $I^*$
12 Kstar $K^*$
13 Qstar $Q^*$
14 rstar $r^*$
15 rkstar $r^{K*}$
16 zstar $z^*$
17 Ktilstar $\tilde{K}^*$
18 Ystar $Y^*$
19 G $G$
20 // model with sticky prices - non linear
21 w $w$
22 L $L$
23 C $C$
24 mc $mc$
25 x $x$
26 I $I$
27 K $K$
28 Q $Q$
29 r $r$
30 rk $r^K$
31 z $z$
32 Ktil $\tilde{K}$
33 Y $Y$
34 UL $U^L$
35 UC $U^C$
36 ptitl $l$
37 pi $\pi$
38 wtild $\tilde{w}$
39 H1 $\mathcal{H}_1$
40 H2 $\mathcal{H}_2$
41 pitarget $\bar{\pi}$
42 mult $\lambda$
43 p $p$
44 Q1 $\mathcal{Q}_1$
45 Q2 $\mathcal{Q}_2$
46 R $R$
47 Dp $D_p$
48 // fiscal shocks
49 taur $\tau^r$
50 tauw $\tau^W$
51 taul $\tau^l$
52 tauk $\tau^K$
53 tauc $\tau^C$
54 tauy $\tau^y$
55 // technological & preferences shocks
56 epsa $\varepsilon^a$
57 epsb $\varepsilon^B$
58 epsi $\varepsilon^I$
59 epsl $\varepsilon^L$
60 ;
61
62 varexo
63 // fiscal shocks
64 e_c $\nu^C$
65 e_l $\nu^l$
66 e_g $\nu^G$
67 e_w $\nu^W$
68 e_r $\nu^r$
69 e_y $\nu^y$
70 e_k $\nu^K$
71 // tech & pref shocks
72 n_a $\eta^a$
73 n_l $\eta^L$
74 n_b $\eta^B$
75 n_i $\eta^I$
76 n_q $\eta^Q$
77 // inflation-related shocks
78 e_pi $\eta^{\pi}$
79 e_taylor $\eta^R$
80 ;
81
82 parameters
83 // deep parameters
84 nu $\nu$
85 alpha $\alpha$
86 sigmal $\sigma_l$
87 sigmac $\sigma_c$
88 eps $\epsilon$
89 teta $\theta$
90 iphi $\varphi^{-1}$
91 Gdpsi $\Psi$
92 beta $\beta$
93 h $h$
94 gY $g_Y$
95 lambdaw $\lambda_w$
96 lambdap $\lambda_p$
97 mhu $\mu$
98 xiw $\xi_w$
99 xip $\xi_p$
100 gammaw $\gamma_w$
101 gammap $\gamma_p$
102 // Taylor's rule
103 rho $\rho$
104 rpi $\rho_pi$
105 ry $\rho_y$
106 rdeltapi $\rho_{\triangle \pi}$
107 rdeltay $\rho_{\triangle \y}$
108 // shocks parameters
109 rhor $\rho^r$
110 rhow $\rho^w$
111 rhol $\rho^l$
112 rhok $\rho^K$
113 rhoc $\rho^C$
114 rhoy $\rho^y$
115 rhog $\rho^g$
116 zetaa $\zeta^a$
117 zetab1 $\zeta^B$
118 // zetab2 $\zeta^B_2$
119 zetai $\zeta^I$
120 zetal$\zeta^L$
121 rhopi $\rho^\pi$
122 // steady state values
123 taurbar $\bar{\tau^r}$
124 tauwbar $\bar{\tau^W}$
125 taulbar $\bar{\tau^l}$
126 taukbar $\bar{\tau^K}$
127 taucbar $\bar{\tau^C}$
128 tauybar $\bar{\tau^y}$
129 zbar $\bar{z}$
130 Gbar $\bar{G}$
131 FixedCost $\Phi$
132 pibar $\bar{\pi}$
133 Rbar $\bar{R}$
134 // Useless parameters (bug in Dynare v4?)
135 wbar $\bar{w}$
136 Lbar $\bar{L}$
137 Cbar $\bar{C}$
138 mcbar $\bar{mc}$
139 xbar $\bar{x}$
140 Ibar $\bar{I}$
141 Kbar $\bar{K}$
142 Qbar $\bar{Q}$
143 rbar $\bar{r}$
144 rkbar $\bar{r^K}$
145 Ktilbar $\bar{\tilde{K}}$
146 Ybar $\bar{Y}$
147 ULbar $\bar{U^L}$
148 UCbar $\bar{U^C}$
149 H1bar $\bar{\mathcal{H}_1}$
150 H2bar $\bar{\mathcal{H}_2}$
151 multbar $\bar{\lambda}$
152 pbar $\bar{p}$
153 Q1bar $\bar{\mathcal{Q}_1}$
154 Q2bar $\bar{\mathcal{Q}_2}$
155 Dpbar $\bar{D_p}$
156 chiKtilL $\bar{\chi^{\tilde{K}L}}$
157 chiYL $\bar{\chi^{YL}}$
158 chiGL $\bar{\chi^{GL}}$
159 chiCL $\bar{\chi^{CL}}$
160 ;
161
162
163
164 // deep parameters
165 gammap = 1-0.477 ;
166 gammaw = 1-0.728 ;
167 xiw = .756 ;
168 xip = .909 ;
169 lambdaw = .5 ;
170 lambdap = .3 ;
171 nu = (1+lambdaw)/lambdaw ;
172 alpha = .3 ;
173 sigmal = 1.26 ;
174 sigmac = 1.6 ;
175 eps = (1+lambdap)/lambdap ;
176 teta = .025 ;
177 iphi = 4 ;
178 beta = .99446327837150;
179 h = .55 ;
180 gY = 0.21468834761075; // calibrated
181 mhu = 1/(eps-1);
182
183 // Taylor's rule
184 rho = .8 ;
185 rpi = 1.5 ;
186 ry = .1 ;
187 rdeltapi = .5 ;
188 rdeltay = .5 ;
189
190 // shocks parameters
191 rhor = .8 ;
192 rhow = .8 ;
193 rhol = .0 ;
194 rhok = .8 ;
195 rhoc = .8 ;
196 rhoy = .0;//.8 ;
197 rhog = .8 ;
198 rhopi = .8 ;
199 zetaa = .8 ;
200 zetab1 = .8 ;
201 zetai = 0 ; //.8 ;
202 zetal = .8 ; //.8 ;
203
204 // steady state values
205
206 taucbar = 1.129202;
207 taukbar = 1;
208 taulbar = 1.298528;
209 taurbar = 1;
210 tauwbar = 0.870431;
211 tauybar = 1;
212
213 pibar = 1.00580514587360;
214 xbar = 1 ;
215 Qbar = 1 ;
216 rbar = 1/beta;
217 zbar = .817183;
218 Gdpsi = zbar/(rbar + teta - 1);
219 rkbar = 1/(Gdpsi*taukbar) ;
220 mcbar = (eps - 1)/eps*tauybar ;
221 wbar = (mcbar*(alpha/(taurbar*rkbar))^alpha)^(1/(1-alpha))*(1-alpha)/taulbar ;
222 chiKtilL = alpha/(1-alpha)*taulbar*wbar/(taurbar*rkbar) ;
223 chiYL = 1/(1+mhu)*(chiKtilL)^alpha ;
224 chiGL = gY*chiYL ;
225 chiCL = chiYL - teta/zbar*chiKtilL - chiGL ;
226 Lbar = (wbar*(nu-1)/nu*tauwbar/taucbar*(chiCL*(1-h))^(-sigmac))^(1/(sigmac+sigmal)) ;
227 Cbar = Lbar*chiCL ;
228 Ktilbar = Lbar*chiKtilL ;
229 Ybar = Lbar*chiYL ;
230 Gbar = Lbar*chiGL ;
231 Kbar = Ktilbar/zbar ;
232 Ibar = teta*Kbar ;
233 FixedCost = mhu*Ybar ;
234
235 ULbar = -Lbar^sigmal ;
236 UCbar = ((1-h)*Cbar)^(-sigmac) ;
237 H1bar = -(Lbar)^(sigmal+1)/(1-beta*xiw) ;
238 H2bar = ((1-h)*Cbar)^(-sigmac)*tauwbar*Lbar/(1-beta*xiw)/taucbar/pibar ;
239 multbar = ((1-h)*Cbar)^(-sigmac)/taucbar ;
240 pbar = 1 ;
241 Q1bar = ((1-h)*Cbar)^(-sigmac)/taucbar*Ybar*tauybar*(eps-1)/eps/(1-beta*xip) ;
242 Q2bar = (1-h)^(-sigmac)*Cbar^(-sigmac)/taucbar*Ybar*tauybar/(1-beta*xip) ;
243 Dpbar = 1 ;
244 Rbar = pibar/beta ;
245
246
247
248 model;
249 // FLEXIBLE PRICE MODEL::
250
251 // Wages:
252 wstar = nu/(nu - 1)*tauc/tauw*epsl*Lstar^sigmal/
253 (Cstar-h*Cstar(-1))^(-sigmac) ; //Equ 1.
254
255 // Prices:
256 mcstar = (eps-1)/eps*tauy; //Equ 2.
257
258 // Capital accumulation:
259 xstar = epsi*Istar/Istar(-1); //Equ 3.
260 Kstar = (1-teta)*Kstar(-1) + (1 - (xstar-1)^2/2*iphi)*Istar; //Equ 4.
261
262 // Investissement equation:
263 Qstar*(1-(xstar-1)^2/2*iphi-xstar*(xstar-1)*iphi) +
264 Qstar(1)/rstar*xstar(1)*Istar(1)/Istar*(xstar(1)-1)*iphi = 1; //Equ 5.
265
266 // Tobin's Q:
267 Qstar = 1/rstar*(tauk(1)*rkstar(1)*zstar(1) -
268 (exp((zstar(1)-zbar)/Gdpsi)-1) + Qstar(1)*(1-teta)); //Equ 6.
269
270 // IS curve:
271 tauc(1)*epsb*(Cstar - h*Cstar(-1))^(-sigmac) =
272 beta*rstar*tauc*epsb(1)*(Cstar(+1)-h*Cstar)^(-sigmac); //Equ 7.
273
274 // Prices frontier:
275 Ktilstar/Lstar = alpha/(1-alpha)*taul*wstar/(taur*rkstar); //Equ 8.
276
277 // Goods market clearing
278 epsa*Ktilstar^alpha*Lstar^(1-alpha) - FixedCost =
279 Cstar + Istar + G + (exp((zstar-zbar)/Gdpsi)-1)*Kstar(-1); //Equ 9.
280
281 // CUR
282 tauk*rkstar = exp((zstar-zbar)/Gdpsi)/Gdpsi; //Equ 10.
283
284 // Aggregate production function
285 Ystar = epsa*Ktilstar^alpha*Lstar^(1-alpha) - FixedCost ; //Equ 11.
286
287 // Marginal cost
288 mcstar = (taur*rkstar/alpha)^alpha*(taul*wstar/(1-alpha))^(1-alpha)/epsa; //Equ 12.
289
290 // Productive capital stock
291 Ktilstar = zstar*Kstar(-1) ; //Equ 13.
292
293 // Governement
294 G = Gbar^(1-rhog)*G(-1)^rhog*exp(e_g); //Equ 14.
295
296
297
298 // NON-FLEXIBLE PRICE MODEL::
299
300 // Wages:
301 UL = -epsb*epsl*ptitl^sigmal; //Equ 15.
302 UC = epsb*(C-h*C(-1))^(-sigmac); //Equ 16.
303 pi*wtild = nu/(1-nu)*H1/H2; //Equ 17.
304 H1 = UL*ptitl+beta*xiw*H1(1); //Equ 18.
305 H2 = UC*tauw*ptitl/tauc/pi+beta*xiw*pitarget(1)^gammaw*pi^(-gammaw)*H2(1); //Equ 19.
306 w^(1-nu) = (1-xiw)*wtild^(1-nu)+ xiw*(pitarget^gammaw*pi(-1)^(1-gammaw)*w(-1)/pi)^(1-nu); //Equ 20.
307 ptitl = (wtild/w)^(-(1+lambdaw)/lambdaw)*L; //Equ 21.
308
309 // Prices:
310 mult = UC/tauc; //Equ 22.
311 pi/pi(-1)^(1-gammap)/pitarget^gammap*p = eps/(eps-1)*Q1/Q2; //Equ 23.
312 Q1 = pi^eps*pi(-1)^(-(1-gammap)*eps)*mult*Y*mc*pitarget^(-eps*gammap)+
313 beta*xip*pi^eps*pi(-1)^(-(1-gammap)*eps)*pitarget^(-gammap*eps)*Q1(1); //Equ 24.
314 Q2 = pi^(eps-1)*pi(-1)^(-(1-gammap)*(eps-1))*mult*tauy*Y*pitarget^(gammap*(1-eps))
315 + beta*xip*pi^(eps-1)*pi(-1)^(-(1-gammap)*(eps-1))*pitarget^(-gammap*(eps-1))*Q2(1); //Equ 25.
316 (1-xip)*p^(1-eps) + xip*(pitarget^gammap*pi(-1)^(1-gammap)/pi)^(1-eps) = 1; //Equ 26.
317
318 // Capital accumulation:
319 x = epsi*I/I(-1) ; //Equ 27.
320 K = (1-teta)*K(-1) + (1 - (x-1)^2/2*iphi)*I; //Equ 28.
321
322 // Investissement equation:
323 Q*(1-(x-1)^2/2*iphi-x*(x-1)*iphi) + beta*mult(1)/mult*Q(1)*x(1)*I(1)/I*(x(1)-1)*iphi = 1; //Equ 29.
324
325 // Tobin's Q:
326 Q/exp(n_q) = beta*mult(1)/mult*(tauk(1)*rk(1)*z(1)-(exp((z(1)-zbar)/Gdpsi)-1) + Q(+1)*(1-teta)); //Equ 30.
327
328 // IS curve:
329 tauc(1)*epsb*(C - h*C(-1))^(-sigmac) =
330 beta*R/pi(1)*tauc*epsb(1)*(C(+1)-h*C)^(-sigmac); //Equ 31.
331
332 // Prices frontier:
333 Ktil/L = alpha/(1-alpha)*taul*w/(taur*rk) ; //Equ 32.
334
335 // Goods market clearing:
336 1/Dp*(epsa*Ktil^alpha*L^(1-alpha) - FixedCost) = C + I + G + (exp((z-zbar)/Gdpsi)-1)*K(-1); //Equ 33.
337
338 Dp = (1-xip)*p^(-eps)+xip*(pitarget^gammap*pi(-1)^(1-gammap)/pi)^(-eps)*Dp(-1); //Equ 34.
339
340 // CUR:
341 tauk*rk = exp((z-zbar)/Gdpsi)/Gdpsi ; //Equ 35.
342
343 // Aggregate production function:
344 Y*Dp = epsa*Ktil^alpha*L^(1-alpha) - FixedCost ; //Equ 36.
345
346 // Marginal cost:
347 mc = (taur*rk/alpha)^alpha*(taul*w/(1-alpha))^(1-alpha)/epsa; //Equ 37.
348
349 // Productive capital stock:
350 Ktil = z*K(-1) ; //Equ 38.
351
352 // Taylor's rule:
353 R = Rbar^(1-rho)*R(-1)^rho*((pi(-1)/pitarget)^rpi*(Y/Ystar)^ry)^(1-rho)
354 *(pi/pi(-1)*pitarget(-1)/pitarget)^rdeltapi * (Y/Y(-1)*Ystar(-1)/Ystar)^rdeltay
355 *exp(e_taylor); //Equ 39.
356
357
358 // Real interest rate:
359 r = R/pi(1) ; //Equ 40.
360
361
362 // Shocks:
363 tauc = taucbar^(1-rhoc)*tauc(-1)^rhoc*exp(e_c) ; //Equ 41.
364 taul = taulbar^(1-rhol)*taul(-1)^rhol*exp(e_l) ; //Equ 42.
365 tauw = tauwbar^(1-rhow)*tauw(-1)^rhow*exp(e_w) ; //Equ 43.
366 taur = taurbar^(1-rhor)*taur(-1)^rhor*exp(e_r) ; //Equ 44.
367 tauy = tauybar^(1-rhoy)*tauy(-1)^rhoy*exp(e_y) ; //Equ 45.
368 tauk = taukbar^(1-rhok)*tauk(-1)^rhok*exp(e_k) ; //Equ 46.
369 epsa = epsa(-1)^zetaa*exp(n_a); //Equ 47.
370 epsl = epsl(-1)^zetal*exp(n_l); //Equ 48.
371 epsb = epsb(-1)^zetab1*exp(n_b); //Equ 49.
372 epsi = epsi(-1)^zetai*exp(n_i); //Equ 50.
373
374 pitarget = pibar^(1-rhopi)*pitarget(-1)^rhopi*exp(e_pi); //Equ 51.
375
376 end ;
377
378 initval;
379 wstar = wbar;
380 Lstar = Lbar ;
381 Cstar = Cbar ;
382 mcstar = mcbar ;
383 xstar = xbar ;
384 Istar = Ibar ;
385 Kstar = Kbar ;
386 Qstar = Qbar ;
387 rstar = rbar ;
388 rkstar = rkbar ;
389 zstar = zbar ;
390 Ktilstar = Ktilbar ;
391 Ystar = Ybar ;
392
393 w = wbar ;
394 L = Lbar ;
395 C = Cbar ;
396 mc = mcbar ;
397 x = xbar ;
398 I = Ibar ;
399 K = Kbar ;
400 Q = Qbar ;
401 r = rbar ;
402 rk = rkbar ;
403 z = zbar ;
404 Ktil = Ktilbar ;
405 Y = Ybar ;
406
407 UL = ULbar ;
408 UC = UCbar ;
409 ptitl = Lbar ;
410 pi = pibar ;
411 wtild = wbar ;
412 H1 = H1bar ;
413 H2 = H2bar ;
414 pitarget = pibar ;
415 mult = multbar ;
416 p = pbar ;
417 Q1 = Q1bar ;
418 Q2 = Q2bar ;
419 Dp = Dpbar ;
420
421 R = Rbar ;
422 G = Gbar ;
423
424 taur = taurbar ;
425 tauw = tauwbar ;
426 taul = taulbar ;
427 tauk = taukbar ;
428 tauc = taucbar ;
429 tauy = tauybar ;
430
431 epsa = 1 ;
432 epsb = 1 ;
433 epsi = 1 ;
434 epsl = 1 ;
435
436 end;
437
438 //check;
439 //return;
440
441 //resid(1);
442 //steady;
443
444
445
446 shocks;
447 var e_c; stderr 0.1;
448 var e_l; stderr 0.1;
449 var e_g; stderr 0.1;
450 var e_w; stderr 0.1;
451 var e_r; stderr 0.1;
452 var e_y; stderr 0.1;
453 var e_k; stderr 0.1;
454 var n_a; stderr 0.1;
455 var n_l; stderr 0.1;
456 var n_b; stderr 0.1;
457 var n_i; stderr 0.1;
458 var n_q; stderr 0.1;
459 var e_pi; stderr 0.1;
460 var e_taylor; stderr 0.1;
461 end;
462
463 estimated_params;
464
465 stderr e_taylor,UNIFORM_PDF,,,0,1;//,INV_GAMMA_PDF, 1,inf;
466 stderr e_pi,UNIFORM_PDF,,,0,1;//INV_GAMMA_PDF, 0.05,inf;
467
468 //$ stderr e_y,UNIFORM_PDF,,,0,10;//INV_GAMMA_PDF, 0.15,inf;
469 //$ stderr e_c,UNIFORM_PDF, , ,0,5;
470 //$ stderr e_l,UNIFORM_PDF,,,0,10;//INV_GAMMA_PDF, 0.3,inf;
471 //$ stderr e_w,UNIFORM_PDF, , ,0,5;
472 //$ stderr e_r,UNIFORM_PDF, , ,0,5;
473 //$ stderr e_k,UNIFORM_PDF, , ,0,5;
474 stderr e_g,UNIFORM_PDF,,,0,5;//INV_GAMMA_PDF, 0.3,inf;
475
476 stderr n_a,UNIFORM_PDF,,,0,5;//INV_GAMMA_PDF, 0.6,inf;
477 stderr n_l,UNIFORM_PDF,,,0,40;//INV_GAMMA_PDF, 1, 2; //UNIFORM_PDF,,,0,15;
478 stderr n_b,UNIFORM_PDF,,,0,10;//INV_GAMMA_PDF, .2, 2;//INV_GAMMA_PDF, 0.3,inf;
479 stderr n_i,UNIFORM_PDF,,,0,5;//INV_GAMMA_PDF, 0.15,inf;
480 //$ stderr n_q,UNIFORM_PDF, , ,0,10;//INV_GAMMA_PDF, 0.6,inf;
481
482 sigmac,NORMAL_PDF, 1.5, 0.5 ; //UNIFORM_PDF,,,1,5;
483 sigmal,NORMAL_PDF, 3.5, 0.5 ;//UNIFORM_PDF,,,0,10;
484
485 xiw,BETA_PDF, 0.75, 0.05;//UNIFORM_PDF,,,0,1;
486 xip,BETA_PDF, 0.75, 0.05;//UNIFORM_PDF,,,0,1;
487
488 gammaw,BETA_PDF, 0.25, 0.15;//UNIFORM_PDF,,,0,1;
489 gammap,BETA_PDF, 0.25, 0.15;//UNIFORM_PDF,,,0,1;
490
491 iphi,NORMAL_PDF, 5.5, 1.5;//UNIFORM_PDF,,,1,10;
492
493 h,BETA_PDF, 0.50, 0.15;//UNIFORM_PDF,,,0,1;
494
495 rho,BETA_PDF, 0.8, 0.05;// UNIFORM_PDF,,,0,1;
496 rpi,NORMAL_PDF, 1.7, 0.1;//UNIFORM_PDF,,,1,2;
497 ry,NORMAL_PDF, 0.125, .05; //UNIFORM_PDF,,,-0.1,1;
498 rdeltapi,NORMAL_PDF, 0.3, 0.1; //UNIFORM_PDF,,,-1,1;
499 rdeltay,NORMAL_PDF, 0.0625, 0.05; //UNIFORM_PDF,,,-1,1;
500
501 //$ rhor, BETA_PDF,0.8,0.1;
502 //$ rhow, BETA_PDF,0.8,0.1;
503 //$ rhol, UNIFORM_PDF,,,-.01,1;//BETA_PDF,0.4,0.15;
504 //$ rhok, BETA_PDF,0.8,0.1;
505 //$ rhoc, BETA_PDF,0.8,0.1;
506 //$ rhoy, UNIFORM_PDF,,,-.01,1;// BETA_PDF,0.4,0.15;
507 rhog, BETA_PDF,0.8,0.1;// UNIFORM_PDF,,,0,1;
508 rhopi, BETA_PDF,0.8,0.1; // UNIFORM_PDF,,,0,1;
509 zetaa, UNIFORM_PDF,,,0,1;//BETA_PDF,0.8,0.15;
510 zetab1,BETA_PDF,0.6,0.1; //UNIFORM_PDF,,,0,1;
511 //$ zetab2, NORMAL_PDF,.0,0.5;
512 //zetai, UNIFORM_PDF,,,0,1;//, BETA_PDF,0.2,0.15;
513 zetal, UNIFORM_PDF,,,0,1;// BETA_PDF,0.7,0.15;
514
515 end;
516
517
518 estimated_params_init;
519 stderr e_taylor,0.08;
520 stderr e_pi,0.22;
521
522 //$ stderr e_y,.01;
523 //$ stderr e_c,0.1;
524 //$ stderr e_l,.1;
525 //$ stderr e_w,0.1;
526 //$ stderr e_r,0.1;
527 //$ stderr e_k,0.1;
528 stderr e_g,1.82;
529
530 stderr n_a,0.59;
531 stderr n_l,2.3;
532 stderr n_b,1.86;
533 stderr n_i,1.5;
534 //$ stderr n_q,3.2;
535
536 sigmac, 1.95;
537 sigmal, 2.75;
538 xiw, 0.4;
539 xip, 0.9;
540 gammaw, 0.83;
541 gammap, 0.96;
542 iphi, 5.63;
543 h, 0.5;
544 rho, 0.8;
545 rpi, 1.50;
546 ry, 0.22;
547 rdeltapi, -.06;
548 rdeltay, 0.03;
549
550 //$ rhor, 0.8;
551 //$ rhow, 0.8;
552 //$ rhol, 0.8;
553 //$ rhok, 0.8;
554 //$ rhoc, 0.8;
555 //$ rhoy, 0.8;
556 rhog, 0.96;
557 rhopi, 0.76;
558 zetaa, 0.79;
559 zetab1, 0.7;
560 //zetai, 0.1;
561 zetal, 0.9;
562
563 end;
564
565
566 varobs Y C I pi R z w;
567
568 options_.noconstant = 1;
569
570 options_.logdata = 1;
571
572
573 estimation(irf=0,datafile=MakeData3,first_obs=46,loglinear,prefilter=1,mode_compute=0,mode_file = acdm_mode,mh_replic=0);
574 //stoch_simul(order=1) pi C w Dp;
575 options_.forecast=8;
576 bvar_forecast 4 ;
Attached Files
To refer to attachments on a page, use attachment:filename, as shown below in the list of files. Do NOT use the URL of the [get] link, since this is subject to change and can break easily.You are not allowed to attach a file to this page.