% Ireland(2010) Replication 
%
% Guidon Fenig
% 

close all;

%----------------------------------------------------------------
% 1. Defining variables
%----------------------------------------------------------------

var y,z,r,g,pi,a,e,lambda;
varexo ea ee ez er ;

parameters bet gamma alpha psi rhor rhop rhog rhoa rhoe siga sige sigz sigr;

%----------------------------------------------------------------
% 2. Calibration
%----------------------------------------------------------------

bet = 0.9987;
gamma = 0.3904; // Habit preference
alpha = 0.0000;  // Backward indexation
psi = 0.10; 
rhor = 1; // Persistence of the interest rate in Taylor rule
rhop = 0.4153; // Persistence of inflation in Taylor rule
rhog = 0.1270; // Persistence of growth in Taylor rule
rhoa = 0.9797; // Persistence: Preference 
rhoe = 0.0000;// Cost push persistance
siga = 100*0.0868;
sige = 100*0.0017;
sigz = 100*0.0095;
sigr = 100*0.0014;

%----------------------------------------------------------------
% 3. Model
%----------------------------------------------------------------

model(linear); 
a=rhoa*a(-1)+ea;
lambda*(1.0046-bet*gamma)*(1.0046-gamma)=1.0046*gamma*y(-1)-(1.0046^2+(bet*(gamma^2)))*y+bet*gamma*1.0046*y(+1)+(1.0046-gamma)*(1.0046-bet*gamma*rhoa)*a-gamma*1.0046*z;
lambda=r+lambda(+1)-pi(+1);
z=ez;
e=rhoe*e(-1)+ee;
(1+alpha*bet)*pi=psi*a-psi*lambda+alpha*pi(-1)+bet*pi(+1)+e;
r=r(-1)+rhop*pi+rhog*g+er;
g=y-y(-1)+z;
end;

%----------------------------------------------------------------
% 4. Computation
%----------------------------------------------------------------

initval;
z = 1.0046;
g=1.0046;
a=1;
e=1;
pi=1.0062;
r=z*pi/bet;
lambda=1.2;
y=0.8333*(z-bet*gamma)/(z-gamma);
end;
resid;
steady;

shocks;
var ea;	stderr siga;
var ee;	stderr sige;
var er;	stderr sigr;
var ez;	stderr sigz;
end;


estimated_params;
bet,beta_pdf,0.9,0.1;
gamma,beta_pdf,0.3,0.1;
alpha,beta_pdf,0.1,0.1;
psi , normal_pdf,0.1,1; 
rhor , gamma_pdf,1,0.1; 
rhop ,  beta_pdf,0.4,0.15; 
rhog ,  beta_pdf,0.1,0.15; 
rhoa ,  beta_pdf,0.9,0.15; 
rhoe ,  beta_pdf,0.1,0.15; 
stderr ea,inv_gamma_pdf,1,inf; 
stderr ee,inv_gamma_pdf,1,inf; 
stderr ez,inv_gamma_pdf,1,inf; 
stderr er,inv_gamma_pdf,1,inf;
end;



varobs pi r y;

estimation (datafile=Data_Ireland,order=1, mh_replic=2000,mh_nblocks=2,mh_drop=0.45,mh_jscale=0.4,mode_compute=6, forecast=4,filter_decomposition,bayesian_irf, irf=12) pi r y;