%----------------------------------------------------------------
% I. Dornbusch Model
%----------------------------------------------------------------


%----------------------------------------------------------------
% II. Defining variables
%----------------------------------------------------------------

var epsilon p s m_d y_d y t_bill;

varexo t_bill_star p_star m epsilon_bar y_bar g;

parameters delta, eta, psi, phi;

%----------------------------------------------------------------
% III. Parameters Values
%----------------------------------------------------------------

delta = 0.5;
eta   = 1;
psi   = 0.5;
phi   = 0.5;


%----------------------------------------------------------------
% IV. Model
%----------------------------------------------------------------

model; 


t_bill     = t_bill_star + s(+1) - s;
m_d        = p(-1) + phi*y - eta*t_bill;
epsilon    = s + p_star - p;
y_d        = y_bar + delta*(s + p_star - p(-1) - epsilon_bar) + g;
p - p(-1)  = psi*(y_d - y_bar) + s(+1) - s;
y_d        = y;
m_d        = m;


end;


%----------------------------------------------------------------
% V. Steady State & checks
%----------------------------------------------------------------

initval;

epsilon_bar = 1;
epsilon     = 1;
y_bar       = 1;
p_star      = 1;
p           = 1;
s           = 1;
t_bill_star = 0.5;
t_bill      = 0.5;
m           = 1;
m_d         = 1;
g           = 0;

end;

steady;

check;

%----------------------------------------------------------------
% VI. Simulation
%----------------------------------------------------------------


endval;

epsilon_bar = 1;
epsilon     = 1;
y_bar       = 1;
p_star      = 1;
p           = 1.1;
s           = 1.1;
t_bill_star = 0.5;
t_bill      = 0.5;
m           = 1.1;
m_d         = 1.1;

end;


/*
shocks;
var m;
periods 4:8;
values 1.1;
end;
*/

/*
shocks;
var g;
periods 1:4;
values 0.1;
end;
*/


options_.maxit_=100;
simul(periods=100);