% my system
var mu $\mu$;
trend_var(growth_factor=mu) X;
var(deflator=X) Y I K C m w d Phi $\Phi$ psi1 $\psi^1$ psi2 $\psi^2$ Psi1 $\Psi^1$;
var(deflator=1/X) Lambda $\Lambda$ Xi $\Xi$;
var Pi $\Pi$ R q a v chi $\chi$ e H ;

varexo eps_a $\epsilon^A$ eps_chi $\epsilon^\chi$ eps_v $\epsilon^v$ eps_e $\epsilon^e$ eps_X $\epsilon^X$; 

parameters theta $\theta$ alpha $\alpha$ delta $\delta$ gamma $\gamma$ eta $\eta$ beta $\beta$ growth $G$ mubar $\mu$ Rbar $R$ Pibar $\Pi$ phi_k $\phi_k$ phi_p $\phi^p$ phi_Pi $\phi^\Pi$ rho_a $\rho^a$ rho_chi $\rho^\chi$ rho_v $\rho^v$ rho_e $\rho^e$ ebar $e$;
theta = 6;
alpha = 0.22;
delta = 0.025;
gamma = 0.035;
eta = 1.5;
beta = 0.99;
growth = 0.02;
mubar = exp(growth);
Rbar = 1.01;
Pibar = 2^0.25; 
phi_k = 32;
phi_p = 162;
phi_Pi = 2.2;
rho_a = 0.9;
rho_chi = 0.95;
rho_v = 0.2;
rho_e = 0.9;
ebar = 3.9;

model;
% (1)
Phi = C^((gamma-1)/gamma) + e^(1/gamma)*m^((gamma-1)/gamma);
% (2)
w = (Phi*C^(1/gamma)*eta)/(a*(1-H)); 
% (3)
R^-1 = beta*((a(+1)/a)*(C(+1)/C)^(-1/gamma)*(Phi(+1)/Phi)^(-1)*Pi(+1)^-1);
% (4)
C*e = m*(1-R^-1)^gamma;
%(5)
psi1 = (phi_k/mubar)*(K/(mubar*K(-1))-1);
% (6)
psi2 = (phi_k/2)*(K(+1)/(mubar*K) - 1)^2 - (phi_k/mubar)*(K(+1)/(mubar*K) -1)*(K(+1)/K) ;
% (7)
(1/chi) + psi1 = beta*((a(+1)/a)*(C(+1)/C)^(-1/gamma)*(Phi(+1)/Phi)^-1* (q(+1)+ (1-delta)/chi(+1) - psi2));
% (8)
Lambda = a/(Phi*C^(1/gamma));
% (9)
Lambda*H*w = (1-alpha)*Xi*Y;
% (10)
Lambda*K(-1)*q = alpha*Xi*Y;
% (11)
phi_p*Lambda*(Pi/mubar - 1)*(Pi/mubar) = (1-theta)*Lambda + theta*Xi + beta*(Lambda(+1)*(Pi(+1)/mubar - 1)*(Pi(+1)/mubar)*(Y(+1)/Y));
% (12) 
Y = K(-1)^alpha*(X*H)^(1-alpha);
% (13)
K = (1-delta)*K(-1) + chi*I;
% (14)
Psi1 = (phi_k/2)*(K/(mubar*K(-1))-1)^2 *K(-1);
% (15)
d = Y - w*H - q*K(-1) - (phi_p/2)*(Pi/mubar - 1)^2*Y;
% (16)
w*H + q*K(-1) + d = C + I + Psi1;
% (17)
R/Rbar = (Pi/Pibar)^phi_Pi + v;
% SHOCK Proccesses
% (18)
ln(a) = rho_a*ln(a(-1)) + eps_a;
% (19)
ln(chi) = rho_chi*ln(chi(-1)) + eps_chi;
% (20)
ln(v) = rho_v*ln(v(-1)) + eps_v;
% (21) 
ln(e) = rho_e*ln(e(-1)) + (1-rho_e)*ln(ebar) + eps_e;
% (22)
mu = exp(growth + eps_X);
end;

initval;
e = ebar;
a = 1;
chi = 1;
v = 1;
mu = exp(growth);
C = 0.45;
w = 4;
R = 1.02;
d = 0.85;
H = 0.19;
Y = 0.6;
end;

shocks;
var eps_X; stderr 0.001  ;
var eps_a; stderr 0.02 ;
var eps_e; stderr 0.01  ;
var eps_chi; stderr 0.02  ;
var eps_v; stderr 0.01  ;
end;

//write_latex_dynamic_model;


steady;
check;

stoch_simul(nograph,order=1);