% Model RMB 2014 - PhD, v. 1.0
%
% Raphael M Barcelos
%
% Base Model - Real Business Cycle - Small Open Economy
%
% Chapter 4, 2014, Uribe, Martin & Stephanie Schmitt-Grohe


%----------------------------------------------------
% 0. Preamble
%----------------------------------------------------
close all;

%----------------------------------------------------
% 1. Variables
%----------------------------------------------------

var y               
    c               
    h               
    k               
    d               
    i               
    tb              
    ca              
    a               
    r               
    p               
    lambda          
;
varexo
    e
;
parameters
    beta            
    sigmae          
    omega           
    alpha           
    delta           
    db              
    rho             
    phi             
    psi             
    gama            
    r_w             
;

%--------------------------------------------------
% 2. Calibra??o
%--------------------------------------------------

r_w =   .04;
beta = 1/(1 + r_w); 
sigmae = .0129;
omega = 1.4550;
alpha = .32;
delta = .10; 
db =    .7442;
rho =   .42; 
phi =   .4; 
psi =   .000742;
gama =  2;

h_ss = ((1-alpha)*(alpha/(r_w+delta))^(alpha/(1-alpha)))^(1/(omega-1)); 
k_ss   = h_ss/(((r_w+delta)/alpha)^(1/(1-alpha)));
i_ss   = delta*k_ss;                                                     
y_ss   = (k_ss^alpha)*(h_ss^(1-alpha));                                   
d_bar  = 0.7442;
d_ss   = db;                                                        
c_ss   = y_ss-i_ss-r_w*d_ss;
tb_ss  = y_ss-c_ss-i_ss;


%--------------------------------------------------
% 3. Model 
%--------------------------------------------------

model;
    d = (1+exp(r(-1)))*d(-1)- exp(y)+exp(c)+exp(i)+(phi/2)*(exp(k)-exp(k(-1)))^2;
    exp(y) = exp(a)*(exp(k(-1))^alpha)*(exp(h)^(1-alpha));
    exp(k) = exp(i)+(1-delta)*exp(k(-1));
    exp(lambda)= beta*(1+exp(r))*exp(lambda(+1)); 
    (exp(c)-((exp(h)^omega)/omega))^(-gama) = exp(lambda);
    ((exp(c)-((exp(h)^omega)/omega))^(-gama))*(exp(h)^omega) = exp(lambda)*(1-alpha)*exp(y); 
    exp(lambda)*(1+phi*(exp(k)-exp(k(-1)))) = beta*exp(lambda(+1))*(alpha*exp(y(+1))/exp(k)+1-delta+phi*(exp(i(+1))-delta*exp(k))); 
    a = rho*a(-1)+e; 
    tb = 1-((exp(c)+exp(i))/exp(y));
    ca = (1/exp(y))*(d-d(-1));      
    p = psi*(exp(d-db)-1);
    exp(r) = r_w+p;
end;

initval;
    r     = log((1-beta)/beta);
    d     = d_ss;
    h     = log(h_ss);
    k     = log(k_ss);
    y     = log(y_ss);
    c     = log(c_ss);
    i     = log(i_ss);
    tb    = 1-((exp(c)+exp(i))/exp(y));
    lambda= log((exp(c)-((exp(h)^omega)/omega))^(-gama));
end;

shocks;
    var e; stderr sigmae;
end;

resid(1);
steady; 
check;
stoch_simul(irf=51);