// the replicate of the SGU2004'optimal fiscal and monetary policy under sticky prices'


var c h m a v mc la pai r tau z g;

varexo  uz ug;

parameters delta A B beta eta theta sig_g sig_z rhoz rhog gbar;

delta=2.9;
A=0.0111;
B=0.07524;
sig_g=0.03;
sig_z=0.02;
beta=1/1.04;
rhoz=0.82;
rhog=0.9;
gbar=0.04;

eta=1.2/(1-1.2);
theta=(-17.5/4*(1+eta)*0.2);



model;
1/c=la*(1+2*A*v-2*sqrt(A*B));//13

delta*c/(1-h)=(1-tau)*z*mc/(1+2*A*v-2*sqrt(A*B));//14

A*v^2-B=1-1/r;//15

la=beta*la(+1)*r/pai(+1);//16

la*pai*(pai-1)=beta*la(+1)*pai(+1)*(pai(+1)-1)+la*eta*z*h/theta*(1+1/eta-mc);//18

m*(1-1/r)+a(+1)/r+tau*z*mc*h=a/pai+g;//19;

(1+A*v+B/v-2*sqrt(A*B))*c+g+theta/2*(pai-1)^2=z*h; //22;

v=c/m;//23;

log(g/gbar)=rhog*log(g(-1)/gbar)+ug;

log(z)=rhoz*log(z(-1))+uz;
end;





initval;
r=1;
tau=0.18;
c=.1816;
h=.2249;
m=.0698;
a=-0.1614;
v=2.6035;
mc=0.8287;
la=5.0561;
pai=0.9615;
z=1;
g=0.04;
end;




shocks;
var uz=sig_z^2;
var ug=sig_g^2;
end;

planner_objective(log(c)+delta*log(1-h));

ramsey_policy(planner_discount=1/1.04,order=1,instruments=(r,tau));