% based on CEE 2005
% quantity rule
% Yang Fei,2015/3/30


var 
k
i
R
q
c
n
w
pi
qk
rk
u
y
mc
mu
m
a
;

varexo
ea
em
;

%%
parameters
alpha
beta
delta
phi
sigma
kappa
rho_a
rho_m
theta
gamma
sigmau
epsi
n_ss
mu_ss
pi_ss
qm_ss
mc_ss
R_ss
rk_ss
w_ss
m_ss
q_ss
ky_ss
cy_ss
;

%%
alpha=0.36;
beta=1.03^(-0.25);
delta=0.025;
phi=1;
sigma=1;
gamma=10;
kappa=5;
rho_a=0.9;
rho_m=0.3;
theta=0.75;
sigmau=0.01;
epsi=6;
n_ss=1/3;
mu_ss=1.017;
pi_ss=mu_ss;
qm_ss=0.44;
mc_ss=(epsi-1)/epsi;
R_ss=pi_ss/beta;
rk_ss=1/beta-(1-delta);
w_ss=mc_ss^(1/(1-alpha))*(1-alpha)*alpha^(alpha/(1-alpha))*rk_ss^(alpha/(alpha-1))/R_ss;
m_ss=w_ss*n_ss/(mu_ss-qm_ss);
q_ss=m_ss*qm_ss;
ky_ss=(R_ss*w_ss*alpha/(rk_ss*(1-alpha)))^(1-alpha);
cy_ss=1-delta*ky_ss;


%%
model;
%eq1
k=(1-delta)*k(-1)+i;

%eq2
R_ss/(R_ss-1)*R=-gamma*q+sigma*c;

%eq3
phi*n=w-sigma*c;

%eq4
R(+1)-pi(+1)-sigma*(c(+1)-c)=0;

%eq5
qk-kappa*(i-i(-1))+beta*kappa*(i(+1)-i)=0;

%eq6
qk=-sigma*(c(+1)-c)+(1-beta*(1-delta))*rk(+1)+beta*(1-delta)*qk(+1);

%eq7
rk=sigmau*u;

%eq8
y=a+alpha*(k(-1)+u)+(1-alpha)*n;

%eq9
a=rho_a*a(-1)+ea;

%eq10
mc=alpha*rk+(1-alpha)*(R+w);

%eq11
pi=beta*pi(+1)+(1-beta*theta)*(1-theta)/theta*mc;

%eq12
w_ss*n_ss*(w+n)=mu_ss*m_ss*(mu+m)-q_ss*q;

%eq13
mu=rho_m*mu(-1)+em;

%eq14
cy_ss*c+delta*ky_ss*i+ky_ss*rk_ss*u=y;

%eq15
mu(-1)+m(-1)-pi-m=0;

%eq16
R+w-rk=k+u-n;

end;

steady;
check;

shocks;
var ea;
stderr 1; 
var em;
stderr 1; 
end;

stoch_simul(linear,irf=20);