// CREDIT CYCLES
// N.KIYOTAKI AND J.MOORE (1997)
// THE FULL MODEL : INVESTMENT AND CYCLES (SECTION III)
// THIS MOD FILE REPLICATE THE FIGURE 3
// CODED IN OCTOBER 2009 BY STEPHANE LHUISSIER (INTERN AT CEPREMAP)

var Q B K;
 
varexo del;


parameters r lambda pi phi a v Qss Bss Kss delss;

r      = 1.01;
lambda = 0.975;
v      = 4.91606;
a      = 1;
pi     = 0.1;
phi    = 20;

//Compute the Steady State
Qss    = (r/(r-1))*(pi*a - (1-lambda)*(1- r + pi*r)*phi )/(lambda*pi + (1-lambda)*(1- r + pi*r));
Kss    = Qss*(1-1/r) + v;
Bss    = 1/(r-1)*(a-phi+lambda*phi)*Kss;
delss  = 0;

model;

Q - 1/r*Q(+1) = K - v;

K = (1-pi)*lambda*K(-1) + pi/(phi+Q-1/r*Q(+1))*((a*(1+del)+Q+lambda*phi)*K(-1)-r*B(-1));

B = r*B(-1) + Q*(K-K(-1)) +phi*(K-lambda*K(-1)) - a*(1+del)*K(-1);

end;

initval;

Q   = Qss;
K   = Kss;
B   = Bss;
del = delss;

end;

steady;
check;

shocks;
var del;
periods 1;
values 0.01;
end;

simul(periods=400);

figure
plot(K(2:40)/Kss)
hold on
plot(B(2:40)/Bss,'.')
plot(Q(2:40)/Qss,'--')
legend('K/K*','B/B*','Q/Q*')