% RBC model (divisible labor, log-linearized) 
% (Steffen Esser)

% Steady state is calculated by a corresponding steady state file

% November 2014

%--------------------------------------------------------------------------
% 1. Defining the variables
%--------------------------------------------------------------------------

var y c i k n w r z kn ck;

varexo e_z;


%--------------------------------------------------------------------------
% 2. Parameter choice
%--------------------------------------------------------------------------

parameters eta a delta betta gam rho n_s k_s c_s y_s;

delta=0.025;
betta=0.99;
eta=1;
rho=0.95;
a=0.64;
gam=2.86894;
n_s=0.3;

%steady state 




%--------------------------------------------------------------------------
% 3. Model
%--------------------------------------------------------------------------

model(linear);

-c=-c(+1)+(1-betta*(1-delta))*r(+1);
w=eta*n+c;
z+(a-1)*n+(1-a)*k(-1)=w;
z+a*(n-k(-1))=r;
y=z+a*n+(1-a)*k(-1);
y=c_s/y_s*c+delta*k_s/y_s*i;
k=(1-delta)*k(-1)+delta*i;
z=rho*z(-1)+e_z;
kn=k(-1)-n;
ck=c-k(-1);
end;

%--------------------------------------------------------------------------
% 4. Computation
%--------------------------------------------------------------------------

initval;

y=0;
c=0;
k=0;
i=0;
n=0;
r=0;
w=0;
z=0;
ck=0;
kn=0;
end;

steady;
check;

shocks;
var e_z;
stderr 0.0049;
end;

stoch_simul(order=1,irf=40) y c k i n w r z;