// RESUSCITATING REPRESENTATIVE AGENT

var A C K N L W RW Y I R LAMBDA;

varexo eps;

parameters bet theta eta sig alp del rho r;

bet   = 0.984;
eta   = 1.000;
sig   = 1.000;
alp   = 0.667;
del   = 0.025;
r     = 0.0163;
theta = 3.3424;
rho   = 0.979;


model;

   %F.O.C.W.R.T. consumption
   C^(-sig) = LAMBDA;

   %F.O.C.W.R.T. leisure
   theta*L^(-eta) = W;

   %F.O.C.W.R.T. labor
   LAMBDA*A*K(-1)^(1-alp)*alp*N^(alp-1) = W;

   %F.O.C.W.R.T. capital
   bet*LAMBDA(+1)*(A(+1)*(1-alp)*K^(-alp)*N(+1)^(alp)+1-del) = LAMBDA;

   %Time endowment
   N + L = 1;

   %Output
   Y = A*K(-1)^(1-alp)*N^(alp);

   %Aggregate resource constraint
   C + I = Y;

   %Law of motion for the capital stock
   K = (1-del)*K(-1) + I;

   %Technological innovation
   log(A) = rho*log(A(-1)) + eps;

   %Real wage
   RW = W/LAMBDA;

   %Real interest rate
   R = (1-alp)*A(+1)*K^(-alp)*N(+1)^(alp)-del;

end;

initval;

A      		 = 1;
C      		 = 0.452831;
K      		 = 4.57847;
N      		 = 0.2;
L      		 = 0.8;
W      		 = 4.17799;
RW     		 = 1.89192;
Y      		 = 0.567292;
I      		 = 0.114462;
R      		 = 0.0162602;
LAMBDA 		 = 2.20833;
end;

steady;
check;

estimated_params; 
bet,        0.984; 
sig,        1.000;  
stderr eps, 0.0072; 
end;

varobs Y; 

estimation(datafile = dataY, mode_compute = 7)
A C K N L W RW Y I R LAMBDA;