set_dynare_seed('mt19937ar', 0); % default Dynare seed

// Example 1 from Collard's guide to Dynare
var y, c, k, a, h, b;
varexo e, u;

parameters beta, rho, alpha, delta, theta, psi, tau;

alpha = 0.36;
rho   = 0.95;
tau   = 0.025;
beta  = 0.99;
delta = 0.025;
psi   = 0;
theta = 2.95;

phi   = 0.1;

model;
c*theta*h^(1+psi)=(1-alpha)*y;
k = beta*(((exp(b)*c)/(exp(b(+1))*c(+1)))
    *(exp(b(+1))*alpha*y(+1)+(1-delta)*k));
y = exp(a)*(k(-1)^alpha)*(h^(1-alpha));
k = exp(b)*(y-c)+(1-delta)*k(-1);
a = rho*a(-1)+tau*b(-1) + e;
b = tau*a(-1)+rho*b(-1) + u;
end;

initval;
y = 1.08068253095672;
c = 0.80359242014163;
h = 0.29175631001732;
k = 11.08360443260358;
a = 0;
b = 0;
e = 0;
u = 0;
end;

shocks;
var e; stderr 0.009;
var u; stderr 0.009;
var e, u = phi*0.009*0.009;
end;


% stoch_simul(order=1, periods=100000, irf=0, noprint, hp_filter=100); %10^5 infeasible on my PC
% stoch_simul(order=1, periods=1000, irf=0, noprint, hp_filter=100);
stoch_simul(order=1, periods=10000, irf=0, noprint, hp_filter=100); % 3.5 min

% Moments calculation
oo_.var(2,1)/(sqrt(oo_.var(2,2)) * sqrt(oo_.var(1,1))) %
corrcoef(oo_.endo_simul(2,:),oo_.endo_simul(1,:))

% with an external HP-filter
jj=size(oo_.endo_simul,2);
Y_H_raw = [oo_.endo_simul(1,1:jj)]';
C_H_raw = [oo_.endo_simul(2,1:jj)]';

Y_H_data = Y_H_raw - hpfilter(Y_H_raw, 100); 
C_H_data = C_H_raw - hpfilter(C_H_raw, 100); 

corr_YhCh_HP=corrcoef(C_H_data, Y_H_data)

disp('difference between oo_.var & oo_.endo_simul');
oo_.var(2,1)/(sqrt(oo_.var(2,2)) * sqrt(oo_.var(1,1))) - corr_YhCh_HP(1,2)