Dynare forums

Hi everybody

I am working on Gali, 2008, ch.6.
Is the following code suitable for simulating a 25 basis points increase (annualized=1 percent) in the exogenous component of the interest rate rule?
The IRFs that I get are almost identical to those in the book,except for price inflation, which fall less than it should.

Thanks in advance

var x y n yn i pip piw rn w wn v a;
varexo eps_v eps_a;
parameters alpha gammap gammaw sigma beta phi thetap thetaw psinya psinwa kappap kappaw lambdap lambdaw rho phip rhoa rhov ew ep;

alpha = 1/3;
sigma = 1;
gammap = 1/5;
gammaw = 1/5;
ew = (1+gammaw)/gammaw;
ep = (1+gammap)/gammap;
thetaw = 3/4;
thetap = 2/3;
beta = 0.99;
phi = 1;
rho = 1/(beta-1);
phip = 1.5;
rhoa = 0.9;
rhov = 0.5;
psinya = (1+phi)/(sigma*(1-alpha)+phi+alpha);
psinwa = (1-alpha*psinya)/(1-alpha);
lambdap = ((1-thetap)*(1-beta*thetap)/thetap)*((1-alpha)/(1-alpha+alpha*ep));
lambdaw = ((1-beta*thetaw)*(1-thetaw))/(thetaw*(1+ew*phi));
kappap = lambdap*alpha/(1-alpha);
kappaw = lambdaw*(sigma + phi/(1-alpha));

model(linear);
x = x(+1) - (1/sigma)*(i - pip(+1) - rn);
x = y - yn;
yn = psinya*a;
y = a + (1-alpha)*n;
rn = sigma*psinya*(rhoa - 1)*a;
pip = beta*pip(+1) + kappap*x + lambdap*(w-wn);
piw = beta*piw(+1) + kappaw*x - lambdaw*(w-wn);
w = w(-1) + piw - pip;
wn = psinwa*a;
i = rho + phip*pip + v;
v = rhov*v(-1)+eps_v;
a = rhoa*a(-1)+eps_a;
end;

shocks;
var eps_a; stderr 0;
var eps_v; stderr 0.25;
end;



resid(1);
steady;




check;

stoch_simul(order=1,irf=12) pip piw x i;

Hi, your code seems correct. The issue is that Gali's IRFs for inflation are annualized. That means you have to multiply the IRF of inflation by 4.