Error: At least one END is missing: the statement may begin

[ger163609]

Where is the problem? If I run the following program I get this error:

Error using dynare (line 120)
Error: At least one END is missing: the statement may begin here.



var y_H, y_F, y, pi_c_H, pi_c_F, pi_H, pi_F, pi, s, g_H, g_F, a, v, i, c_H, c_F, mc_H, mc_F;

varexo epsilon_a epsilon_g_H epsilon_g_F epsilon_v;

parameters sigma, rho, phi, alpha, beta, theta, epsilon, phi_pi, phi_y, rho_a, rho_v, rho_g_H, rho_g_F, omega, lambda, sigma_alpha;

alpha = 0.5;
beta = 0.99;
theta = 2/3;
epsilon = 6;
sigma = 1;
phi = 1;

rho_v = 0.5;
rho_a = 0.9;
rho_g_H = 0.9;
rho_g_F = 0.9;

phi_y = 0.5/4;
phi_pi = 1.5;


rho = -1*log(beta);
lambda = (1-theta)*(1-beta*theta)/theta;
omega = sigma + (sigma-1)*(1-2*alpha);
sigma_alpha = sigma/(1-2*alpha+2*alpha*omega);

model (linear);

c_H = c_H(+1) - 1/sigma*(i-rho-pi_c_H(+1));
c_F = c_F(+1) - 1/sigma*(i-rho-pi_c_F(+1));
pi_H = beta*pi_H(+1) + lambda*mc_H;
pi_F = beta*pi_F(+1) + lambda*mc_F;
y_H = c_H + g_H + alpha*omega/sigma*s;
y_F = c_F + g_F - alpha*omega/sigma*s;
pi_c_H = pi_H + alpha*(s-s(-1));
pi_c_F = pi_F - alpha*(s-s(-1));
y_H - y_F = 1/sigma_alpha*s - g_F + g_H;
mc_H = sigma*c_H + phi*y_H - (1+phi)*a + alpha*s;
mc_F = sigma*c_F + phi*y_F - (1+phi)*a - alpha*s;
y = (y_H + y_F)/2;
pi = (pi_H + pi_F)/2;
i = phi_pi*pi + phi_y*y + v;
a = rho_a*a(-1) + epsilon_a;
g_H = rho_g_H*g_H(-1) + epsilon_g_H;
g_F = rho_g_F*g_F(-1) + epsilon_g_F;
v = rho_v*v(-1) + epsilon_v;

end;

initval;

y_H = 0;
y_F = 0;
y = 0;
pi_H = 0;
pi_F = 0;
pi = 0;
i = 0;
g_H = 0;
g_F = 0;
a = 0;
v = 0;
pi_c_H = 0;
pi_c_F = 0;
mc_H = 0;
mc_F = 0;
s = 0;
c_H = 0;
c_F = 0;

end;

steady;

check;

shocks;

var epsilon_g_H = 1^2;
var epsilon_g_F = 1^2;
var epsilon_a = 1^2;
var epsilon_v = 1^2;

end;

stoch_simul(irf=12);

[HoutanBastani]

Rename your file. try is a keyword in Matlab.