//Tax Reduction Policies of the Productive Sector and Its Impacts on Brazilian Economy
//Celso Costa and Armando Sampaio, 2014

var Y C CR CNR I G K L R R_b W B TAX BAL P PI Welfare S_c S_l FI_l FI_k A;
varexo e_sc e_sl e_l e_k e_a;
parameters a b varfi alfa beta delta tau_c tau_k tau_l tau_p sigma psi omega ro_sc ro_sl ro_l ro_k ro_a teta qui PEN;

varfi = 6;
alfa = 0.39;
beta = 0.985;
delta = 0.025;
tau_c = 0.1594;
tau_k = 0.0813;
tau_l = 0.1730;
tau_p = 0.105;
omega = 0.39;
sigma = 2;
psi = 1.5;
ro_sc = 0.9;
ro_sl = 0.9;
ro_l = 0.9;
ro_k = 0.9;
ro_a = 0.9;
teta = 0.85;
qui = 0.1;
a = 0.5;
b = 1.5;
PEN = 0.1;

model(linear);
#Ass = 1;
#S_css = 1;
#S_lss = 1;
#FI_lss = 1;
#FI_kss = 1;
#Bss = 1;
#PIss = 0;
#R_bss = 1.02;
#Pss = 1.44;
#Rss = 0.072;
#Wss = 0.94;
#Yss = 1.17;
#Kss = 7.46;
#Iss = 0.19;
#Lss = 0.36;
#CRss = 1.38;
#CNRss = 0.06;
#Css = 0.87;
#Gss = 0.11;
#BALss = -0.06;
#TAXss = 0.34;
Kss*K = (1-delta)*Kss*K(-1) +Iss*I;                                                                                                                               // 1 - Lei de Movimento do Capital
(CRss^sigma)*(Lss^psi)*(1+tau_c)*(S_l + sigma*CR + psi*L) = (Wss/Pss)*((W-P)*(1-tau_l-tau_p) + tau_l*FI_l);                                                       // 2 - Oferta de Trabalho
(1/beta)*(S_c - sigma*CR) = (1-delta)*(S_c(+1) - sigma*CR(+1)) + (Rss/(Pss*(1+tau_c)))*((S_c(+1) - sigma*CR(+1) + R(+1) - P(+1))*(1-tau_k) + tau_k*FI_k(+1));     // 3 - Equação de Euler 1
R_b + S_c(+1) - S_c = sigma*(CR(+1) - CR) + PI(+1);                                                                                                               // 4 - Equação de Euler 2
(1+tau_c)*Pss*CNRss*(P + CNR) = 0;                                                                                                                                // 5 - Regra de Consumo das Famílias Não-Ricardianas
Css*C = (1-omega)*CRss*CR + omega*CNRss*CNR;                                                                                                                      // 6 - Consumo Agregado
Y = A + alfa*K(-1) + (1-alfa)*L;                                                                                                                                  // 7 - Função de Produção
W - P = Y - L;                                                                                                                                                    // 8 - Nível dos Salários
R - P = Y - K(-1);                                                                                                                                                // 9 - Nível do Retorno do Capital
PI = beta*PI(+1) + ((1-teta)*(1-teta*beta)/teta)*((1-alfa)*W - A + alfa*R);                                                                                       // 10 - Equação de Phillips
beta*(B - R_b) - B(-1) = Pss*Gss*(P+G) - BALss*BAL - TAXss*TAX;                                                                                                   // 11 - Restrição Orçamentária do Governo
Gss*G = qui*Bss*B(-1);                                                                                                                                            // 12 - Regra de Gastos do Governo
TAXss*TAX = Pss*tau_c*(Css*(P+C) + Iss*(P+I)) + Wss*Lss*tau_l*(W + L - FI_l) + Rss*Kss*tau_k*(R + K(-1) - FI_k);                                                  // 13 - Receita Tributária
BALss*BAL = Wss*Lss*tau_p*(W+L);                                                                                                                                  // 14 - Resultado da Previdencia Social
R_bss*R_b = a*Yss*Y + b*PIss*PI;                                                                                                                                  // 15 - Regra de Taylor
Yss*Y = Css*C + Iss*I + Gss*G;                                                                                                                                    // 16 - Equilíbrio no Mercado de Bens
Welfare = (CRss^(1-sigma))*CR - (Lss^(1+psi))*L;                                                                                                                  // 17 - Variação no Bem-Estar das Famílias Ricardianas
A = ro_a*A(-1) + e_a;                                                                                                                                             // 18 - Choque de Produtividade
S_c = ro_sc*S_c(-1) + e_sc;                                                                                                                                       // 19 - Choque na Preferencia Intertemporal
S_l = ro_sl*S_l(-1) + e_sl;                                                                                                                                       // 20 - Choque na Oferta de Trabalho
FI_l = ro_l*FI_l(-1) + e_l;                                                                                                                                       // 21 - Choque na Alíquota do Imposto de Renda do Trabalho
FI_k = ro_k*FI_k(-1) + e_k;                                                                                                                                       // 22 - CHoque na Alíquota do Imposto de Renda do Capital
end;

steady;
check;
model_info;
model_diagnostics;
check;

shocks;
var e_l; 
stderr 1;
end;

shocks;
var e_k; 
stderr 1;
end;

shocks;
var e_a;
stderr 1;
end;

shocks;
var e_sc;
stderr 1;
end;

shocks;
var e_sl;
stderr 1;
end;

stoch_simul(order=1, periods=0,irf=48, conditional_variance_decomposition =[1:48]);